; Omnitel 2400S+                                       Version 1.00 10-Jan-1992
; (c) 1990/1991 Hugo Fiennes

modem_initialise ()
  {
  integer oldtx=port_txspeed(),oldrx=port_rxspeed()

  port_rxclear()
  port_txspeed(9600)
  port_rxspeed(9600)

  type "AT&F"+cr
  pause(100)
  port_rxclear()

  type "ATX4E0Q0V1&C1&D2S0=0S9=1S10=5S37=0"+cr
  pause(200)
  port_rxclear()
  type "ATB0C1S2=255\J0\G0\Q2\T0\V1\N3"+cr

  if (waitfor("OK",150))
    {
    port_txspeed(oldtx)
    port_rxspeed(oldrx)
    return(0)
    }

  port_txspeed(oldtx)
  port_rxspeed(oldrx)
  return(1)
  }

modem_shutdown ()
  {
  return(1)
  }

modem_connect ()
  {
  integer mode=0

  port_dtr(1)
  port_rts(1)

  if (port_txspeed()==75)
    {
    mode=4
    }

  port_txspeed(9600)
  port_rxspeed(9600)

  type "ATB"+$str(mode)+"O"+cr

  return(_processmessage(""))
  }

modem_disconnect ()
  {
  port_rts(0)
  port_dtr(0)
  pause 50
  port_dtr(1)
  port_rts(1)
  type cr
  }

modem_dial (string number[40],integer how)
  {
  string dialtype[1]
  integer mode=0

  port_dtr(1)
  port_rts(1)

  if (port_txspeed()==75)
    {
    mode=4
    }

  port_txspeed(9600)
  port_rxspeed(9600)
  port_rxclear()

  if (how==0)
    {
    dialtype="P"
    }
  else
    {
    dialtype="T"
    }

  type "ATB"+$str(mode)+"D"+dialtype+number+cr

  return(_processmessage(""))
  }

modem_errorcontrol (string option[10])
  {
  integer oldtx=port_txspeed(),oldrx=port_rxspeed()
  port_txspeed(9600)
  port_rxspeed(9600)
  port_rxclear()

  set(linklevel,none)

  if (comparei(option,"off"))
    {
    type("AT\N0"+cr)
    }

  if (comparei($left(option,3),"mnp"))
    {
    if (comparei(option,"mnp5"))
      {
      type("AT\N3%C1"+cr)
      }
    else
      {
      type("AT\N3%C0"+cr)
      }
    }

  if (comparei(option,"vasscom"))
    {
    type("AT\N0"+cr)
    set(linklevel,vasscom)
    }

  waitfor("OK"+$chr(13)+$chr(10),100)
  pause(50)
  port_txspeed(oldtx)
  port_rxspeed(oldrx)
  }

modem_answer ()
  {  
  string response[30]

  type "ATS0=1"+cr

  repeat
    {
    response=$modeminput(30,modem_replywait)
    }
  until(strcmp($left(response,7),"CONNECT")==0)

  return(_processmessage(response))
  }

modem_standard (string option[10])
  {
  if (comparei(option,"v21"))
    {
    port_txspeed(300)
    port_rxspeed(300)
    return
    }
  if (comparei(option,"v22"))
    {
    port_txspeed(1200)
    port_rxspeed(1200)
    return
    }
  if (comparei(option,"v22bis"))
    {
    port_txspeed(2400)
    port_rxspeed(2400)
    return
    }
  prints "Modem standard "+option+" is not supported."+newline
  }

_processmessage (string already[30])
  {
  string retcode[30]

  if (len(already)==0)
    {
    ; Wait for message
    retcode=$modeminput(30,modem_replywait)

    if (len(retcode)==0)
      {
      retcode=$modeminput(30,modem_replywait)
      }
    }
  else
    {
    retcode=already
    }

  prints retcode+newline

  ; Check for NO DIALTONE/BUSY
  switch(retcode)
    {
    case$("BUSY")
      {
      return(2)
      }
    case$("NO DIALTONE")
      {
      return(3)
      }
    case$("DIALLING BLOCKED")
      {
      return(4)
      }
    }

  if (compare($left(retcode,7),"CONNECT"))
    {
    return(0)
    }

  modem_disconnect()
  return(1)
  }
